完善所有剩余功能，后续bug修复后即准备发布正式版并向下移植

- 将命名空间改为“fzsd”
- 完善交互器
- 添加管理员命令（/function admin.fzsd:<...>）
- 添加启动函数，用于自动升级等功能
- 添加重装、深度安装、深度卸载、深度重装函数

data/fzsd/functions/logger/clear_data.mcfunction

@@ -0,0 +1,6 @@
+# 调用者：fzsd:logger/uninstall
+
+## 日志
+tellraw @a [{"nbt": "fzsd.level.info", "interpret": true, "storage": "fzsd:logger"}, {"text": "已删除日志配置!"}]
+
+data remove storage fzsd:logger fzsd

data/fzsd/functions/logger/install.mcfunction

@@ -0,0 +1,31 @@
+##### 使用方式，形如：tellraw @a [{"nbt": "fzsd.exception.load_without_install_exception", "interpret": true, "storage": "fzsd:logger"}, {"text": "计分板"}]
+
+## 根
+data modify storage fzsd:logger fzsd.root set value '[{"text": "", "color": "white"}, {"text": "[", "color": "dark_gray"}, {"text": "FZSD", "color": "gold"}, {"text": "]", "color": "dark_gray"}]'
+
+## 不同日志等级
+### error 800
+data modify storage fzsd:logger fzsd.level.error set value '[{"text": "", "color": "red"}, {"nbt": "root", "interpret": true, "storage": "fzsd:logger"}, {"text": "[错误]"}]'
+### alert 600
+data modify storage fzsd:logger fzsd.level.alert set value '[{"text": "", "color": "yellow"}, {"nbt": "fzsd.root", "interpret": true, "storage": "fzsd:logger"}, {"text": "[提醒]"}]'
+### info 500
+data modify storage fzsd:logger fzsd.level.info set value '[{"text": "", "color": "green"}, {"nbt": "fzsd.root", "interpret": true, "storage": "fzsd:logger"}, {"text": "[信息]"}]'
+### debug 400
+data modify storage fzsd:logger fzsd.level.debug set value '[{"text": "", "color": "dark_aqua"}, {"nbt": "fzsd.root", "interpret": true, "storage": "fzsd:logger"}, {"text": "[调试]"}]'
+### fine 300
+data modify storage fzsd:logger fzsd.level.fine set value '[{"text": "", "color": "gray"}, {"nbt": "fzsd.root", "interpret": true, "storage": "fzsd:logger"}, {"text": "[详细]"}]'
+
+## 异常
+data modify storage fzsd:logger fzsd.exception.load_without_install_exception set value '[{"nbt": "fzsd.level.error", "interpret": true, "storage": "fzsd:logger"}, {"text": "模块在未安装时被加载："}]'
+
+## 首次安装时日志等级默认为一般消息
+execute unless data storage fzsd:logger fzsd.levels.current run data modify storage fzsd:logger fzsd.levels.current set value 500
+
+## 读取日志等级存入缓存
+execute store result score fzsd.logger.level fzsd.variable.integer run data get storage fzsd:logger fzsd.levels.current
+
+## 标记为已安装
+data modify storage fzsd:installed fzsd.logger set value 1b
+
+## 调试
+execute if score fzsd.logger.level fzsd.variable.integer matches ..400 run tellraw @a [{"nbt": "fzsd.level.debug", "interpret": true, "storage": "fzsd:logger"}, {"text": "已安装系统组件：日志"}]

data/fzsd/functions/logger/level/debug.mcfunction

@@ -0,0 +1,7 @@
+
+## debug 400
+data modify storage fzsd:logger fzsd.levels.current set value 400
+execute store result score fzsd.logger.level fzsd.variable.integer run data get storage fzsd:logger fzsd.levels.current
+
+## 日志
+tellraw @a [{"nbt": "fzsd.level.info", "interpret": true, "storage": "fzsd:logger"}, {"text": "日志等级设为调试"}]

data/fzsd/functions/logger/level/fine.mcfunction

@@ -0,0 +1,7 @@
+
+## fine 300
+data modify storage fzsd:logger fzsd.levels.current set value 300
+execute store result score fzsd.logger.level fzsd.variable.integer run data get storage fzsd:logger fzsd.levels.current
+
+## 日志
+tellraw @a [{"nbt": "fzsd.level.info", "interpret": true, "storage": "fzsd:logger"}, {"text": "日志等级设为详细"}]

data/fzsd/functions/logger/level/info.mcfunction

@@ -0,0 +1,7 @@
+
+## info 500
+data modify storage fzsd:logger fzsd.levels.current set value 500
+execute store result score fzsd.logger.level fzsd.variable.integer run data get storage fzsd:logger fzsd.levels.current
+
+## 日志
+tellraw @a [{"nbt": "fzsd.level.info", "interpret": true, "storage": "fzsd:logger"}, {"text": "日志等级设为一般信息"}]

data/fzsd/functions/logger/load.mcfunction

@@ -0,0 +1,7 @@
+# 调用者：#fzsd:logger/init
+
+## 读取日志等级存入缓存
+execute store result score fzsd.logger.level fzsd.variable.integer run data get storage fzsd:logger fzsd.levels.current
+
+## 调试
+execute if score fzsd.logger.level fzsd.variable.integer matches ..400 run tellraw @a [{"nbt": "fzsd.level.debug", "interpret": true, "storage": "fzsd:logger"}, {"text": "已加载系统组件：日志"}]

data/fzsd/functions/logger/uninstall.mcfunction

@@ -0,0 +1,10 @@
+## 调用者：#fzsd:logger/uninstall
+
+## 删除安装标记
+data remove storage fzsd:installed fzsd.logger
+
+## 调试
+execute if score fzsd.logger.level fzsd.variable.integer matches ..400 run tellraw @a [{"nbt": "fzsd.level.debug", "interpret": true, "storage": "fzsd:logger"}, {"text": "已卸载系统组件：日志"}]
+
+## 询问是否清除数据
+execute if score fzsd.logger.level fzsd.variable.integer matches ..600 run tellraw @s [{"nbt": "fzsd.level.alert", "interpret": true, "storage": "fzsd:logger"}, {"text": "您要删除日志配置吗，它将会永久失去！(真的很久！)"}, {"text": "[确定]", "color": "dark_red", "clickEvent": {"action": "suggest_command", "value": "/function #fzsd:logger/clear_data"}, "hoverEvent": {"action": "show_text", "contents": {"text": "将命令填入聊天框"}}}]